forked from historicalsource/total-carnage
-
Notifications
You must be signed in to change notification settings - Fork 1
/
Copy pathRBOSS.ASM
5498 lines (4544 loc) · 99.7 KB
/
RBOSS.ASM
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
**************************************************************
*
* Orcus software: Eugene Jarvis, Shawn Liptak
* Initiated: 7/12/91 from RBOSS SMASH TV
*
* Modified: Shawn Liptak, 9/25/91 -Started big fix
* Shawn Liptak, 11/7/91 -Done??
*
*
* COPYRIGHT (C) 1992 WILLIAMS ELECTRONICS GAMES, INC.
*
*.Last mod - 1/13/92 19:04
**************************************************************
.TITLE "Orcus"
.WIDTH 132
.OPTION B,D,L,T
.MNOLIST
.include "mproc.equ"
.include "disp.equ"
.include "sys.inc"
.include "gsp.inc"
.include "game.equ"
.include "imgtbl.glo"
.include "audit.equ"
.include "shawn.hdr" ;My macros
.include "orcus.tbl"
;Symbols externally defined
.ref SUCIDE,GANIOF,BEGINOBJ2,GAMSTATE
.ref PLYROBJS,PLYRPRCS,P1DATA,P2DATA,WAVE,STATUS2
.ref FLASHME,KILALL,KILL
.ref SCRADD2,BONE,HEXTOASC
.ref FRANIM,FRANIMQ,GETFPAL,HALT
.ref RD15FONT,WRLD,STRCNRMO,STRLNRMO
.ref CYCLE_TABLE,START_PJ,DOIT
.ref FLMUP1,FLMUP2,FLMUP3,FLMUP4,FLMUP5
.ref RNDRNGS,RNDRNG
.ref NOSHOOT,FLMUP6
.ref RUN_AWAY
.ref BLUEEXP,FIREEXP,XBOOM2,BOOM3,BURST
.ref ONESND,ONESNDOVR
.ref SHAKER,OUT_FLG
.ref getcloseplyr
.ref YZSORT
.ref LIMO,TRY_RCK,PCNT,ICONS_DN
.ref aud_addnumplyrs
.ref ABOOBJUMP
;Symbols defined in this file
.def bossd_t
.def ORCHINT ;Image
.DEF bloflg
;Sound headers
.ref LOVEIT
musicsnd .word 0f3feH,10,08009H,0 ;Boss music
gscottsnd .word 0f9f7H,16,0814bH,0 ;Great scott
landsnd .word 0fc88H,30,08030H,0 ;Land from a jump
laughsnd .word 0f194H,30,080f2H,0 ;When plyr dies
exp1snd .word 0fc80H,7,0803eH,0 ;Explosion
exp2snd .word 0fd80H,10,080d9H,0 ;^
;pain1snd .word 0f985H,20,080f6H,0 ;
;pain2snd .word 0f985H,20,080f9H,0 ;
groansnd .word 0f985H,20,08113H,0 ;Groan
groanlndsnd .word 0f185H,20,08113H,0 ;^ interruptable
oofsnd .word 0f985H,20,08114H,0 ;Oof
yowl1snd .word 0f985H,30,08115H,0 ;
yowl2snd .word 0f985H,30,08116H,0 ;
roarsnd .word 0f990H,40,08117H,0 ;Roar
roarlongsnd .word 0f990H,120,08117H,0 ;Roar
houchsnd .word 0f985H,20,08120H,0 ;
hyowlsnd .word 0f985H,20,08122H,0 ;
stvpainsnd .word 0f985H,30,08123H,0 ;
bubl1snd .word 0f5e5H,20,08131H,0 ;Blood bubbling
bubl2snd .word 0f0e5H,20,08130H,0 ;^
myeyesnd .word 0f9e0H,110,08118H,0 ;
myarmsnd .word 0f9e0H,120,08119H,0 ;
myheadsnd .word 0f9e0H,70,08121H,0 ;
msllnchsnd .word 0f290H,10,080b9H,0 ;Missile launch
;msllnchsnd .word 0f290H,10,080b6H,0 ;Missile launch
mslexpsnd .word 0f470H,10,08048H,0 ;Missile explosion
tungsnd .word 0f290H,10,080b6H,0 ;Tongue launch
youwillsnd .word 0f9f7H,32,08153H,0 ;
;Process subtypes
SUBLGUN .equ 1 ;Left gun controller
SUBRGUN .equ 2 ;Right gun controller
SUBTHRST .equ 3 ;Thrust
SUBNOSEF .equ 4 ;Nose flamers
SUBANI .equ 5 ;Eye/mouth animation
SUBWEAPON .equ 9 ;Missile/tongue launcher
SUBBOSSHALT .equ 080H ;Halts boss processes
ZACC .equ 01000H ;z accel constant
;Ram allocation for orcus
.bss bossram,0
.bss bossjmphi,16 ;!0=In high jump (Must preceed bossd_t)
.bss bossd_t,25*16*4 ;Boss object data structure
.bss bossxv,32 ;XV
.bss bossyv,32 ;YV
.bss bosszv,32 ;Z velocity
.bss bossz,32 ;Z pos (height)
.bss hdani_p,32 ;*Head animation process or 0
.bss iani_p,32 ;*Eye animation process or 0
.bss mani_p,32 ;*Mouth animation process or 0
.bss armani_p,32 ;*Arm animation process or 0
;*Must stay in order!!!
;ARMSTAT .equ 0
GUNDIR .equ 010H
GUNMODE .equ 020H
GUNSWP .equ 030H
GUNNUM .equ 040H
GUNBLOW .equ 050H
.bss larmdata,0 ;
.bss larmstat,16 ;LArm status:-=Gone, 0=OK, 1=On fire
; 2=Exploding, 3=Stump
.bss lgundir,16 ;LGun direction 0-5
.bss lgunmode,16 ;LGun shooting mode 0-7
.bss lgswflg,16 ;LGun sweep direction flag 0=Down, !0=Up
.bss lgunnum,16 ;Gun # (0)
.bss lgunblow,16 ;LGun ready to blow: 0=No, !0=Yes
.bss rarmdata,0 ;
.bss rarmstat,16 ;RArm same as ^
.bss rgundir,16 ;^
.bss rgunmode,16 ;^
.bss rgswflg,16 ;^
.bss rgunnum,16 ;Gun # (1)
.bss rgunblow,16 ;^
.bss hdstat,16 ;!0=Head blown off
.bss shldrstat,16 ;!0=Shoulders blow off and # hits for big blow
.bss leyestat,16 ;!0=L eye blown out
.bss reyestat,16 ;!0=R eye blown out
.bss bodystat,16 ;!0=Everything blown out
.bss bossmode,16 ;Boss mode, -=Firing, 0=Stationary, +=Hopping
.bss bmtimer,16 ;Boss mode timer
.bss bloflg,16 ;-=Blow on; 0=No blow, +=Blow on but weapons OK
.bss bflmrstat,16 ;!0=Flamer on
.bss bossramend,0
BOSSJMPHI .set -16 ;Offset from bossd_t
;Boss data struct
BOOBJ .set 00H ;*Parts obj
BODAMR .set 020H ;Damage resistance (0-?)
BOAFRM .set 028H ;Current animation frame
BODAM .set 030H ;Damage
*0040H=IMAGE 1 ETC.
AX .equ 43 ;Ani point offsets
AY .equ -84
.bss bombtotal,16 ;Total bombs at start of boss
********************************
* Orcus boss monster (Process)
SUBR BOSS
; movi musicsnd,a0
; calla ONESND
movi roarlongsnd,a0
calla ONESNDOVR
SLEEPK 30
clr a0 ;0CHlear out boss variables
movi bossram,a1
bossclr move a0,*a1+
cmpi bossramend,a1
jrlo bossclr
move @GAMSTATE,a0
cmpi INAMODE,a0
jreq bi100
movk AUDBOSS1,a0
calla aud_addnumplyrs
bi100 move @P1DATA+BMBSUSED,a0
move @P2DATA+BMBSUSED,a1
add a0,a1
move a1,@bombtotal ;For bomb message
movk 1,a0
move a0,@lgundir ;Init LR gun angles down
move a0,@rgundir
move a0,@rarmdata+GUNNUM
move @WORLDTLX+16,a0 ;Get starting coord
addi 200,a0
sll 16,a0
move @WORLDTLY+16,a1
subi 150,a1 ;Y Off screen
sll 16,a1
clr a11 ;Damage level
callr boss_init ;Initialize
movi bossd_t,a8 ;A8=*Boss data struct
CREATE BOSSPID,cycle_eye
CREATE BOSSPID|SUBNOSEF,nose_flamers
movi larmdata,a11
CREATE BOSSPID|SUBLGUN,gun
movi rarmdata,a11
CREATE BOSSPID|SUBRGUN,gun
CREATE BOSSPID|SUBWEAPON,weapon_launcher
CREATE BOSSPID|SUBBOSSHALT,boss_halter
callr bossjump_center
movi 60*15,a2 ;No blows for awhile
;TURMELL
; movi 60*17,a2 ;No blows for awhile
callr set_bloflg
SLEEPK 2
CREATE0 gscott_snd
movi 60*3,a0
jruc b30
;** A8 Must not be trashed!!
bosslp
move @PCNT,a0
sll 32-6,a0
jrnz bl15
movi 08140H,a1
move @PLYRPRCS,a0,L
jrz bl10
move *a0(LEG_PRC),a0,L
move a1,*a0(SHOECNT) ;Always with shoes
bl10 move @PLYRPRCS+32,a0,L
jrz bl15
move *a0(LEG_PRC),a0,L
move a1,*a0(SHOECNT)
bl15 move @bossmode,a0
jrnz b50
move @bmtimer,a0 ;0BHoss main loop
subk 1,a0
move a0,@bmtimer
jrge b50 ;Same mode?
movk 0fH,a0 ;>New Mode
callr rnd
sll 3,a0 ;*8
addi bossmode_t,a0
movb *a0,a0
move a0,@bossmode
movi 220,a0
callr rndrng0
addi 60,a0
b30 move a0,@bmtimer ;Set new time
b50 move @bodystat,a0
jrnz b1000 ;Totally blown?
move @HALT,a0
jrz b100 ;No halt?
clr a0
move a0,@bossxv,L
move a0,@bossyv,L
move a0,@bosszv,L
jruc b1300
b100 move @iani_p,a0,L ;0BHig eyes
jrnz b200 ;Animating?
movi eyequad_t,a9 ;0FHollow player
clr a0 ;X offset
movi 80,a1 ;Y offset
callr bossseekp_ani32
callr aniboss
b200 move @hdstat,a0 ;>Little head
jrnz b400 ;Head blown?
move @hdani_p,a0,L
jrnz b400 ;Animating?
move @PLYRPRCS,a0,L
jrz b220
move *a0(DEAD),a0
jrnz b260 ;P1 dead?
b220 move @PLYRPRCS+32,a0,L
jrz b300
move *a0(DEAD),a0
jrz b300 ;P2 alive?
b260 move a8,a6
movi grinner,a8 ;Smile
movi hdani_p,a11
CREATE BOSSPID|SUBANI,aniseqq
move a6,a8
movi laughsnd,a0
calla ONESND
b300
movi hdquad_t,a9 ;0FHollow player
clr a0 ;X offset
movi 80,a1 ;Y offset
callr bossseekp_ani32
callr aniboss
b400 move @mani_p,a0,L ;>Mouth and tongue
jrnz b450
movk 2,a0 ;33%
callr rndrng0
move a0,a0
jrnz b450
movi mouthrnd_t,a1
movi mani_p,a2
callr ani_rnd
b450 movi 99,a0 ;01H% New gun mode
callr rndrng0
move a0,a0
jrnz b500
movk 7,a0
callr rndrng0
move a0,@lgunmode
movk 7,a0
callr rndrng0
move a0,@rgunmode
**** Jump setup code
b500 move @bossz,a0,L
jrnz b1000 ;Jump in progress?
move @bflmrstat,a0
jrnz b1000 ;Flamers on?
move @bossmode,a0
jrn b1000 ;Firing?
move *a8,a0,L
move *a0(OYPOS),a2
subk 25,a2
movk 1,a0
callr rnd
jrz b530 ;Skip P1? So we don't pick on P1
move @PLYROBJS,a0,L
jrz b530
move *a0(OYPOS),a1
cmp a2,a1
jrlt b540 ;P1 Y < OrcY?
b530 move @PLYROBJS+32,a0,L
jrz b570
move *a0(OYPOS),a1
cmp a2,a1
jrge b570 ;P2 Y >= OrcY?
b540 movk 4,a0 ;Short jmps
move a0,@bossmode
b570 move @WORLDTLX+16,a4 ;A4=World X
move @WORLDTLY+16,a5 ;A5=World Y
callr boss_scrntst
jrz b600 ;On screen?
movk 1,a0 ;Jmp rnd
move a0,@bossmode
jruc b750
b600 move @bossmode,a0
jrle b1000 ;Fire or sit still mode?
cmpi 4,a0 ;>Short jmp
jrne b650
clr a0 ;X offset
movi 80,a1 ;Y offset
callr boss_getcloseplyr
jrz b1000
movi 75,a2
movi ZACC/2/2,a3
b630 move *a0(OYPOS),a1 ;Get plyr XY
move *a0(OXPOS),a0
callr bossjump_zacc ;Jump!
jruc b1000
b650 cmpi 6,a0 ;0BHig jump
jrne b670
movi roarsnd,a0
calla ONESND
clr a0 ;X offset
movi 80,a1 ;Y offset
callr boss_getcloseplyr
movi 180,a2
movi ZACC/2,a3
move a0,a0
jrnz b630
jruc b1000
b670 subk 5,a0
jrne b750
movi yowl1snd,a0
calla ONESND
movi 60,a0 ;>Jump on plyr
callr rndrng0
subk 30,a0
move a0,a6 ;X offset +/-30
movi 30,a0
callr rndrng0
subk 15,a0
move a0,a7 ;Y offset
callr getplyr
jrz b750 ;No player?
move *a0(OYPOS),a1 ;Get plyr XY
move *a0(OXPOS),a0
add a6,a0 ;Add in offset
add a7,a1
sub a4,a0 ;0CHheck bounds
sub a5,a1
cmpi 25,a0 ;XMin
jrge b680
movk 25,a0
b680 cmpi 370,a0 ;XMax
jrle b690
movi 370,a0
b690 cmpi -10,a1 ;YMin
jrge b700
movi -10,a1
b700 cmpi 180,a1 ;YMax
jrle b800
movi 180,a1
jruc b800
b750 movi 129,a0
callr rndrng0
addi 45,a0
move a0,a2
movi 249,a0
callr rndrng0
addi 75,a0 ;Rnd X dest
move a2,a1 ;Rnd Y dest
move @bossmode,a3
subk 2,a3 ;2=Jump rnd X
jrne b790
movk 10,a1 ;Y dest
movi 60*4,a2
move a2,@bmtimer ;Sit at top for tongues
b790 subk 1,a3 ;3=Jump rnd Y
jrne b800
movi 200,a0 ;X dest
b800 add a4,a0 ;Add in world XY
add a5,a1
movi 100,a2
callr bossjump ;Jump!
b1000
move @bossz,a2,L ;>Update Z height
jrle b1300 ;No Z?
move a2,a3
move @bosszv,a0,L
subi ZACC,a0
move a0,@bosszv,L
add a0,a2 ;A2=Z+ZV
jrgt b1200 ;In air?
sub a2,a0 ;>Land
move a0,a4
move *a8(BOSSJMPHI),a0
jrz b1100
callr boss_setlow
b1100 movk 20,a10
calla SHAKER
movi landsnd,a0
calla ONESND
movi groanlndsnd,a0
calla ONESND
move @bossmode,a0
subk 5,a0
jrne b1120 ;!Sml jmp?
movk 5,a0 ;17%
callr rndrng0
move a0,a0
jrnz b1130 ;Keep jumping?
b1120 clr a0
move a0,@bossmode ;Sit still
b1130 move a4,a0
clr a2
move a2,@bosszv,L
move a2,@bossxv,L
move a2,@bossyv,L
move a2,*a8(BOSSJMPHI)
b1200 move a2,@bossz,L
callr vel_setz
move *a8(BOSSJMPHI),a0
jrnz b1300 ;High?
srl 16,a2
subk 16,a2 ;0-15 Z is low
jrlt b1300 ;Too low?
callr boss_sethi
movk 1,a0
move a0,*a8(BOSSJMPHI)
b1300 move @bossxv,a0,L
move @bossyv,a1,L
callr vel_set
SLOOP 1,bosslp
;Boss mode table
;0=Sit still, 1=Rnd jump, 2=Jmp X rnd Y top, 3=Jmp X center Y rnd
;4=Small jmp at plyr, 5=Jmp at plyr, 6=BigJmp
;7=Center jmp (blow)
bossmode_t
.byte 0,0,0,1,2,2,3,3,4,4,4,5,5,5,6,6
********************************
* Boss jump to screen center
* Trashes A0-A2
SUBRP bossjump_center
PUSH a7
CREATE BOSSPID,bossjump_center2
PULL a7
rets
bjc2 SLEEPK 1
SUBRP bossjump_center2
move @bossz,a0,L
jrnz bjc2 ;Jump in progress?
move @bflmrstat,a0
jrnz bjc2 ;Flamers on?
movk 7,a0
move a0,@bossmode
move @WORLDTLX+16,a0
move @WORLDTLY+16,a1
addi 200,a0
addi 100,a1
movi 100,a2 ;Time
movi SUCIDE,a3
move a3,-*sp,L ;We'll DIE
********************************
* Boss jump
* A0=DestX
* A1=DestY
* A2=Time
* Trashes A3
SUBRP bossjump
movi ZACC/2,a3
********************************
* Boss jump with custom ZACC
* A0=DestX
* A1=DestY
* A2=Time
* A3=ZACC
SUBRP bossjump_zacc
PUSH a2,a4,a7,a8,a10
move @bossd_t,a8,L ;A8=*1st obj
move *a8(OYPOS),a4
sub a4,a1
sll 16,a1
divs a2,a1 ;YV
move a1,@bossyv,L
move a0,a1
move *a8(OXPOS),a4
addi AX,a4 ;X center
sub a4,a1
sll 16,a1
divs a2,a1 ;XV
move a1,@bossxv,L
move a3,a1
mpys a2,a1 ;ZV
move a1,@bosszv,L
movk 1,a0
move a0,@bossz,L
movi BOSSPID|SUBTHRST,a0 ;Kill thrusters
calla KIL1C
movk 4,a10
CREATE BOSSPID|SUBTHRST,thrusters_fire
PULL a2,a4,a7,a8,a10
rets
********************************
* Do great scott sound (Process)
SUBRP gscott_snd
SLEEP 50
movi gscottsnd,a0
calla ONESND
DIE
********************************
* Halt boss processes if halt on (Process)
SUBRP boss_halter
bhlp SLEEPK 8
move @HALT,a0
jrz bhlp ;No halt?
movi BOSSPID,a0
movk 01fH,a1
movk 8,a2
calla KOP_ALL
jruc bhlp
********************************
* Player score
* A1=Amount to add (8 digit bcd)
* A11=*Bullet object that killed
SUBRP boss_scorehit
PUSH a2
move *a11(OPLINK),a0,L
movb *a0(MYPLYR),a0 ;A0=Player #
movi P1DATA,a2
subk 1,a0
jreq bsch1
movi P2DATA,a2
bsch1 calla SCRADD2 ;Do it!
PULL a2
rets
********************************
* Score and send bonus word to score panel
* A1=Amount to add (8 digit bcd)
* A8=*Src obj
* A11=*Bullet obj
SUBRP boss_scorebonusword
PUSH a2,a7,a9,a10
move *a11(OPLINK),a10,L
movb *a10(MYPLYR),a0 ;A0=Player #
movi P1DATA,a2
subk 1,a0
jreq bsbw10 ;P1?
movi P2DATA,a2
bsbw10 move *a2(TBIGSTF),a0
addk 1,a0
move a0,*a2(TBIGSTF) ;Total big stuff destroyed
calla SCRADD2
movk 1,a9
CREATE FUTUREPID,BONE
PULL a2,a7,a9,a10
rets
********************************
* Part of boss monster takes a hit
* A0=*Obj that hit
* A8=*Boss obj
SUBR orcus_hit
mmtm sp,a1,a2,a3,a4,a5,a6,a7,a9,a10,a11
movk 1,a1
move a1,@OUT_FLG ;Stop scan
move @bodystat,a1
jrnz ohx ;All blown?
move a0,a11 ;A11=*Obj that hit
move *a11(OID),a10 ;Get subtype
sll 32-3,a10
srl 32-3-4,a10 ;*16
jrz oh100 ;Bomb?
move @shldrstat,a1
jrz oh100 ;All blown?
move @bloflg,a0
jrn oh100 ;Blow in progress?
callr bosshit_big
oh100 move *a11(OXVEL),a1,L
move *a11(OYVEL),a2,L
addi buldat_t,a10 ;A10=*Data_t
move *a10,a9 ;>Push back
sra a9,a1
sra a9,a2
callr boss_addxy
move *a10,a0 ;>Shake
addk 10,a0
callr boss_addrndxy
movk 3,a0 ;75%
callr rnd
jrnz ohx ;No damage?
movi 01f1f0000H,a9
CREATE0 FLASHME
move *a8(OPLINK),a9,L ;A9=*Obj data struct
move *a10(080H),a2 ;A2=Weapon damage
jrnn oh140 ;!Bomb?
movk 1,a0
callr rnd
move a0,a2 ;Bomb damage 0 or 1
oh140 movb *a9(BODAMR),a0
jrz oh150
addk 1,a2
srl a0,a2 ;Shift damage down
oh150 callr damage_react
move *a9(BODAM),a3 ;A3=Damage
add a2,a3
move a2,a4
callr boss_chknblowpart ;Check for special destruction
move @bloflg,a0 ;0DaHmage correct part for stupid plyrs
jrnz oh400 ;Blow or lockout in progress?
movk 7,a0 ;13%
callr rnd
jrnz oh400 ;Skip xfer?
move @larmstat,a0
subk 3,a0
jrlo oh400 ;!Stump?
move @rarmstat,a0
subk 3,a0
jrlo oh400 ;!Stump?
movi 9*040H,a1 ;Part 10
move @larmstat,a0
jrnn oh300
movi 10*040H,a1 ;Part 11
move @rarmstat,a0
jrnn oh300
movi 4*040H,a1 ;Part 5
move @leyestat,a0
jrz oh300 ;LEye OK?
movi 5*040H,a1 ;Part 6
move @reyestat,a0
jrz oh300 ;REye OK?
movi 8*040H,a1 ;Part 9
move @hdstat,a0
jrz oh300 ;Head OK?
movi 6*040H,a1 ;Part 7
move @shldrstat,a0
jrnz oh400 ;Top blown?
oh300 addi bossd_t,a1
cmp a1,a9
jreq oh400 ;Same part?
move *a1(BODAM),a0
add a4,a0
cmpi 48,a0
jrhs oh350 ;Maxed?
PUSH a3,a8,a9
move *a1,a8,L ;Get obj
move a1,a9
move a0,a3 ;A3=Damage
callr boss_chknblowpart ;Check for special destruction
move a4,a2
callr damage_set
PULL a3,a8,a9
oh350
oh400 move a4,a2
cmpi 47,a3
jrls oh500 ;!Maxed?
callr damage_xfer ;Xfer damage to other parts!
movi 47,a3
oh500 callr damage_set
move *a10(080H),a1 ;Get score
abs a1
callr boss_scorehit
ohx mmfm sp,a1,a2,a3,a4,a5,a6,a7,a9,a10,a11
rets
; Bullet subtype data table
;SUBLZR 1 ;Regular shots
;SUBSPRY 2 ;Spray
;SUBFIRE1 3 ;Flame thrower
;SUBGRND 4 ;Arcing balls
;SUBNOSTP 5 ;Non-stopping rockets
;SUBSPDG1 6 ;Fast blue balls
buldat_t
.word -2,-3,-3,-3, 0, 0,-2,0 ;Shift count
.word -1, 1, 1, 3, 4, 3, 1,0 ;Damage/score
********************************
* Make pieces from where boss is hit
* A11=*Obj that hit
* Trashes A0-A7,A9
SUBRP bosshit_big
PUSH a8,a11
movk 3,a0
callr rnd
sll 5,a0 ;*32
addi bigpain_t,a0
move *a0,a0,L
calla ONESND
movi t72blst_l,a9
move *a11(OXVEL),a6,L
move *a11(OYVEL),a7,L
move *a11(OXPOS),a0
move *a11(OSIZEX),a2
srl 1,a2 ;/2
add a2,a0
move *a11(OYPOS),a1
move *a11(OSIZEY),a2
srl 1,a2 ;/2
add a2,a1
subk 22,a1
sll 16,a0 ;X
sll 16,a1 ;Y
movi T72BLAST1,a2
move *a11(OZPOS),a3
addk 30,a3
movi DMAWNZ+M_NOCOLL,a4 ;No collisions
movi CLSDEAD,a5
PUSH a0,a1,a7
calla BEGINOBJ2
CREATE BOSSPID,FRQDELDIE
PULL a0,a1,a7
sll 1,a6 ;*2
sll 1,a7
calla BEGINOBJ2
CREATE BOSSPID,FRQDELDIE
PULL a8,a11
rets
t72blst_l
LW T72BLAST2,2
LW T72BLAST3,4
LW T72BLAST4,4
LW T72BLAST5,4
LW T72BLAST6,4
LW T72BLAST7,4
LWL0 T72BLAST8,4
bigpain_t
.long yowl1snd,yowl2snd,roarsnd,stvpainsnd
********************************
* Add random XY to boss position
* A0=XY Max (word)
* Trashes A0-A3
SUBRP boss_addrndxy
sll 15,a0 ;Make long
move a0,a3
calla RNDRNGS
move a0,a2 ;Y
move a3,a0
calla RNDRNGS
move a0,a1 ;X
********************************
* Add XY to boss position
* A1=Delta X
* A2=Delta Y
SUBRP boss_addxy
PUSH a2,a3,a4
movi bossd_t,a4
jruc baxy5
baxylp move *a0(OXVAL),a3,L
add a1,a3
move a3,*a0(OXVAL),L
move *a0(OYVAL),a3,L
add a2,a3
move a3,*a0(OYVAL),L
addk 32,a4
baxy5 move *a4+,a0,L
jrnz baxylp ;More?
PULL a2,a3,a4
rets
********************************
* Heads react to damage
* A2=New damage
SUBRP damage_react
cmpi 2,a2
jrhs damage_react2 ;Always pain?
movk 0fH,a0 ;6%
callr rnd
jrnz drxx
SUBRP damage_react2
mmtm sp,a2,a3,a4,a5,a6,a7,a8,a9,a10,a11
movk 4,a0 ;>Random pain
move @hdstat,a1
jrnz dr1 ;Head blown?
movk 6,a0
dr1 callr rndrng0
sll 5,a0 ;*32
addi painsnd_t,a0
move *a0,a0,L
calla ONESND
move @hdstat,a0 ;>Lil head pain
jrnz dr5 ;Head blown?
movi hdani_p,a2
move *a2,a0,L
jrz dr2 ;Head inactive?
calla KILL
clr a0
move a0,*a2,L
dr2 movi hddam_t,a1
callr randseq ;Start new ani
dr5 move @bodystat,a0
jrnz drx ;Body blown?
movi iani_p,a2 ;0BHig eyes pain
move *a2,a0,L
jrz dr50 ;Eye inactive?
calla KILL
clr a0
move a0,*a2,L
dr50 movi eyedam_t,a1
callr randseq ;Start new ani
drx mmfm sp,a2,a3,a4,a5,a6,a7,a8,a9,a10,a11
drxx rets
painsnd_t