forked from historicalsource/total-carnage
-
Notifications
You must be signed in to change notification settings - Fork 1
/
Copy pathICONS.ASM
1674 lines (1579 loc) · 31.7 KB
/
ICONS.ASM
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
**************************************************************
*
* Software: Mark Turmell
* Initiated: 4/26/89
*
* Modified: Shawn Liptak, 10/27/91 -Orcus mods
*
* COPYRIGHT (C) 1992 WILLIAMS ELECTRONICS GAMES, INC.
*
*.Last mod - 1/9/92 18:38
**************************************************************
.TITLE "TOTAL CARNAGE"
.WIDTH 132
.OPTION B,D,L,T
.MNOLIST
.INCLUDE "MPROC.EQU" ;MPROC EQUATES
.INCLUDE "DISP.EQU" ;DISPLAY PROC. EQUATES
.include "sys.inc" ;z unit system equates
.include "gsp.inc"
.include "macros.hdr" ;macros definitions
.INCLUDE "IMGTBL.GLO"
.INCLUDE "GAME.EQU"
.INCLUDE "MAC2.ASM" ;MACRO 2 DEFINITIONS
.INCLUDE "AUDIT.EQU"
;SOUND
.REF MTING
;SYMBOLS EXTERNALLY DEFINED
.REF WAITTNT,SBOMB,INEXP
.REF RANGRAND,HALT,OBJON,OBJOFF,RANDPER,P1DATA,P2DATA,INAWARP
.REF GPALOBJ,STFOBJ,INSOBJ,PLYROBJS,FRANIM,SPAWN_MISL,RINGS
.REF CURRENT,WAVE,GAMSTATE,COLCYC
.REF HULK_DN,LOTS_FLAG,BOSS,STATUS2,SETDET,timerp1,timerp2
.REF MAXHULK,MAXLYR,MAXAHMD,MAXFND,MAXSKPR,SPAWN_MOM,SPAWN_HJP
.REF SPAWN_HULKS,SPAWN_RUNNR,SPAWN_JEEPS,SKIPR_DN
.REF SPAWN_FND,SPAWN_LYR,SPAWN_AHMD,SPAWN_T72,SPAWN_SKIPR,SPAWN_SNEUT2
.REF SPAWN_SNEUT,SPAWN_JEEPS2,HTYPE
;SYMBOLS DEFINED IN THIS FILE
.DEF AUTO_SBMB
.DEF GET_VALID_XY,ICN3,ICONS_DN,ICN4,ICN5,ICN5A,ICN6,ICN7
.DEF SEND_ICON,ICN1,FREETOT,ICLIST,CLEANUP,IP,DO_ALL_STUFF,ICN2
.DEF WAVE_RAM,DOLORD,ICN8,ICN9,SEND_GEMS
;UNINITIALIZED RAM DEFINITIONS
.BSS WAVE_RAM,6*16*10 ;6=ELEMENTS,16=WORD SIZE
.BSS TMP,16
.BSS ICONS_DN,16
.BSS FREETOT,16 ;FREE MEN COLLECTED
.BSS ICLIST,32
.BSS PALTMP,16*32*2 ;ALLOCATE 2 X COLOR AREA IN RAM
.TEXT
REALLY .WORD 0F9F7H,050H,08148H,0 ;YOUR REALLY GOOD
AMNOT .WORD 0F9F7H,050H,08149H,0 ;NOT
DO_ALL_STUFF
CALLA GPALOBJ ;ALLOCATE A COLOR PALETTE
CALLA STFOBJ ;STUFF OBJECT DATA
MOVE A13,*A0(OPLINK),L
CALLA INSOBJ ;INSERT OBJECT INTO LIST
RETS
;SEND_ICON - PUT A RANDOM ICON TYPE ONTO PLAYFIELD AT VALID SPOT
;ICLIST POINTS TO CURRENT SELECTION LIST OF ICONS! THIS IS CHANGED WHEN
;RECTANGLE COLLISIONS ARE CHANGED.
SEND_ICON:
SLEEP 4*60
CLR A0
MOVE A0,@ICONS_DN
ICONLUP MOVE @ICONS_DN,A0
JRNZ IDIE
MOVE @HALT,A0
JRNE NOKZ ;IF HALT ON, SKIP THIS
MOVK 030,A9 ;ICON 20 WIDE
CALLR GET_VALID_XY
JRNC GOOD
AGAIN SLEEPK 4 ;ON HEAD, TRY AGAIN
JRUC ICONLUP
NOKZ SLEEP 4*60 ;4
JRUC ICONLUP
GOOD:
;A10,A11 ARE VALID
MOVE @ICLIST,A9,L ;RAM PNTR TO CURRENT ICON LIST
CLR B0
MOVK 30,B1
CALLA RANGRAND
;NEVER A 0
SLL 3,A0
ADD A9,A0 ;RANDOM ICON NOW SELECTED
MOVB *A0,A14
; MOVK GRENX,A14
; MOVK NSTPX,A14
JRZ NOKZ
CMPI XTRAX,A14
JRNE NOX
;TRYING TO PLACE AN EXTRA MAN ICON! SHOULD I?
MOVE @GAMSTATE,A0
CMPI INAMODE,A0
JRZ AGAIN
MOVE @FREETOT,A0
CMPI 1,A0 ;2 ;3 PER CIRCUIT CAN BE PICKED UP!
JRGT AGAIN
MOVI 185,A0
CALLA RANDPER
JRNC AGAIN
NOX
CMPI KEYX,A14
JRNE NOXA
;TRYING TO PLACE A KEY ICON! SHOULD I?
; MOVE @INAWARP,A0
; JRZ AGAIN
NOXA
SLL 5,A14
ADDI ICINIT,A14
MOVE *A14,A14,L
CALLR DO_ALL_STUFF
MOVE A0,A8
MOVE A10,*A8(OYPOS),W
MOVE A11,*A8(OXPOS),W
WAITAA
;A9=COLOR TO FLASH WITH
;A8=IMAGE PNTR TO FLASH
;FLASH MORE?
MOVK 8,A11
FLP MOVE *A8(OPAL),A10,L
ORI 09090000H,A10
MOVE A10,*A8(OPAL),L
MOVE *A8(OFLAGS),A0,W
ORI 8,A0
MOVE A0,*A8(OFLAGS),W
SLEEPK 2
ANDI 0FFFFH,A10
MOVE A10,*A8(OPAL),L
MOVE *A8(OFLAGS),A0,W
ANDI 0FFF7H,A0
MOVE A0,*A8(OFLAGS),W
SLEEPK 5
DSJ A11,FLP
SLEEP 4*54-35 ;ABOUT 3 1/2 SECONDS ON SCREEN!
MOVE @HALT,A0
JRNZ WAITAA
;BLINK ICON
WAITB
MOVK 7,A10
;ABOUT 1 SECOND OF BLINK
BK
MOVE A8,A0
CALLA OBJOFF
SLEEPK 5
MOVE A8,A0
CALLA OBJON
SLEEPK 5
DSJS A10,BK
SLEEPK 30
; MOVE *A8(OIMG),A0
; CMPI KEY,A0
; JRNZ IPIP
;
; MOVE @KEYS_LOST,A0 ;KEY ICONS NOT PICKED UP
; INC A0
; MOVE A0,@KEYS_LOST
;
;WHEN AN ICON IS PICKED UP, SEND ITS PROCESS TO HERE SO IT MAY BE CLEANED UP!
;IPIP
MOVE A8,A0
CALLA DELOBJ ;ICONS NOW GONE FOREVER!
IP
SLEEP 190 ;140
;TIE THIS SLEEP IN WITH DIFFICULTY SETTING!
;MAYBE PLACE SOME BOMBS DOWN
MOVE @P1DATA+BMB_CNT,A0
MOVE @P2DATA+BMB_CNT,A1
ADD A0,A1
CMPI 13,A1 ;7
JRGT NOBMB
;MAYBE DROP SOME BOMBS
MOVI 550,A0
CALLA RANDPER
JRNC NOBMB
ANDI 03,A0
;A0=BMB # TO LAYDOWN
MOVE A0,A9
JRNZ NOMOD
MOVK 1,A9
NOMOD CREATE CMAN,LAYBMB
NOBMB
;TRY TO LAY SOME JEWELS DOWN
MOVE @WAVE,A0
SLL 4,A0
ADDI CASHTBL,A0
MOVE *A0,A0
JRZ ICONLUP ;DON'T WANT ANY IN THIS AREA!
CALLA RANDPER
JRNC ICONLUP
;ANY ON SCREEN?
CLR A1
NOT A1
MOVI CLSNEUT|TYPICON|SUBCSH,A0
CALLA EXISTOBJ
JRNZ ICONLUP
;NO CASH ON SCREEN! LETS GET SOME.
;CHECK TO SEE IF ICONPID IS STILL AROUND.
;IF NOT, THEN PLYRS ARE LEAVING ARENA
MOVE @GAMSTATE,A0
CMPI INAMODE,A0
JRZ ICONLUP
CREATE CMAN,SEND_CSH
JRUC ICONLUP
;CASH PILE PERCENTAGE FOR CIRCUIT 1 WAVES.
CASHTBL .WORD 0,0,0,40,350,0,500,500,500,500 ;WAVE #
.WORD 500,350,350,0,450,500,0,110,110 ;18
.WORD 500,500,40,450,0,0,400,150,0
.WORD 500,500,0,0,0,500,500,0,0
.WORD 500,500,500,500,500,0,500,500,500
.WORD 500,500,500,500,500,500,500,500,500
;DO JEWELS ON GROUND
SEND_CSH
SLEEP 120
LAYJWL MOVE @HALT,A0
JRNE AAIN ;IF HALT ON, SKIP THIS
MOVI 090,A9 ;JEWEL AREA 75 WIDE X 75 HIGH
CALLR GET_VALID_XY
JRNC AGOOD2
AAIN SLEEPK 4 ;ON HEAD OR IN RECTANGLE, TRY AGAIN
JRUC LAYJWL
AGOOD2
;A10=UPLFT X OF AREA
;A11=UPLFT Y OF AREA
SWAP A10,A11
CLR A0
MOVE A0,@TMP
MOVK 8,B0 ;10
MOVK 20,B1 ;25
CALLA RANGRAND
MOVE A0,A9 ;A9=# OF CASH ITEMS TO LAY DOWN
CMPI 16,A0 ;19
JRNC LPQ
ANDI 07,A0
INC A0
MOVE A0,@TMP
LPQ
CLR B0
MOVI 75,B1
CALLA RANGRAND
MMTM SP,A10,A11
ADD A0,A10
CLR B0
MOVI 50,B1
CALLA RANGRAND
ADD A0,A11
MOVE @TMP,A1
JRZ LPQ1
;SINGLES TO BE DISPERSED!
MOVE A1,A0
SLL 5,A0
ADDI CZ2LST,A0
JRUC LPQ2
LPQ1 ANDI 07,A0
SLL 5,A0
ADDI CZLST,A0
LPQ2 MOVE *A0,A14,L
CALLA DO_ALL_STUFF
MOVE A0,A8
CLR A0
MOVE A0,*A8(OPLINK),L
MOVE A10,*A8(OXPOS),W
MOVE A11,*A8(OYPOS),W
MMFM SP,A10,A11
MOVE *A8(OIMG),A0,L
CMPI USFLG,A0
JRZ USS
CREATE CMAN,ANIJEW
USS SLEEPK 4 ;3
DEC A9
JRNZ LPQ
IDIE DIE
ANIJEW MOVE *A8(OIMG),A0,L
MOVI JM1,A9
CMPI JEM1,A0
JRZ DOJ
CMPI JEM2,A0
JRZ AX2
MOVI JM3,A9
DOJ
MOVE A9,A10
DOJ0 CLR A1
JSRP FRANIM
JRC DOJ1
MOVE *A8(OZPOS),A0
CMPI 500,A0
JRZ EXT
JRUC DOJ0
DOJ1
SLEEPK 10
MOVE A10,A9
DOJ2 CLR A1
JSRP FRANIM
JRC EXT
MOVE *A8(OZPOS),A0
CMPI 500,A0
JRZ EXT
JRUC DOJ2
EXT
DIE
AX2 MOVI JM2,A9
JRUC DOJ
JM1
.LONG JEM1
.WORD 4
.LONG JEM1B
.WORD 4
.LONG JEM1C
.WORD 4
.LONG JEM1D
.WORD 4
.LONG JEM1C
.WORD 4
.LONG JEM1B
.WORD 4
.LONG 0
JM2 .LONG JEM2B
.WORD 4
.LONG JEM2C
.WORD 4
.LONG JEM2D
.WORD 4
.LONG JEM2C
.WORD 4
.LONG JEM2B
.WORD 4
.LONG JEM2
.WORD 4
.LONG 0
JM3 .LONG JEM3B
.WORD 4
.LONG JEM3C
.WORD 4
.LONG JEM3D
.WORD 4
.LONG JEM3C
.WORD 4
.LONG JEM3B
.WORD 4
.LONG JEM3
.WORD 4
.LONG 0
CZLST .LONG CASH0,CNS0,GLD0,USFLG0,USFLG0,USFLG0,CASH0,CNS0
CZ2LST .LONG 0,CASH0,GLD0,CNS0,USFLG0,USFLG0,CASH0,GLD0,USFLG0
CNS0:
.LONG 0,0,JEM1
; .WORD 70,DMAWNZ|M_NOCOLL,CLSNEUT|TYPICON|SUBCSH
.WORD 70,DMAWNZ,CLSNEUT|TYPICON|SUBCSH
.LONG 0,0
USFLG0:
.LONG 0,0,USFLG
.WORD 70,DMAWNZ,CLSNEUT|TYPICON|SUBCSH
.LONG 0,0
GLD0:
.LONG 0,0,JEM2
; .WORD 70,DMAWNZ|M_NOCOLL,CLSNEUT|TYPICON|SUBCSH
.WORD 70,DMAWNZ,CLSNEUT|TYPICON|SUBCSH
.LONG 0,0
CASH0:
.LONG 0,0,JEM3
; .WORD 70,DMAWNZ|M_NOCOLL,CLSNEUT|TYPICON|SUBCSH
.WORD 70,DMAWNZ,CLSNEUT|TYPICON|SUBCSH
.LONG 0,0
CLEANUP
;WHEN AN ICON IS PICKED UP, SEND ITS PROCESS TO HERE SO IT MAY BE CLEANED UP!
MOVE A8,A0
CALLA DELOBJ ;ICONS NOW GONE FOREVER!
MOVE A9,A0 ;STILL SLEEP APPROX WHAT WAS TO HAPPEN
CALLA PRCSLP
JRUC IP
GET_VALID_XY:
;A9=SUB VALUE FROM RIGHT EDGE
MOVK 10,B0
MOVI 400,A0
SUB A9,A0
MOVE A0,B1
CALLA RANGRAND
MOVE A0,A11 ;A11=X POSITION
MOVK 10,B0
MOVI 260,A0
SUB A9,A0
MOVE A0,B1
CALLA RANGRAND
MOVE A0,A10 ;A10=Y POS
MOVE @PLYROBJS,A0,L
JRZ A
CALLR CK_HDS
JRC NOK
A MOVE @PLYROBJS+32,A0,L
JRZ OK
CALLR CK_HDS
JRNC OK
NOK
SETC
RETS
OK:
;WILL NOT LAND ON ANYONES HEAD
;NOW CHECK PLAYERS CURRENT RECTANGLES!
MOVE @WORLDTLX,A0,L
SRL 16,A0
ADD A0,A11
MOVE @WORLDTLY,A0,L
SRL 16,A0
ADD A0,A10
ANDI 0FFFFH,A10
MOVE @CURRENT,A0,L ;CURRENT RECT LIST
JRZ OUT
NEXT0 MOVE *A0+,A1,W
JRZ OUT
SUB A9,A1 ;ICON 20 PIXELS WIDE
CMP A1,A11
JRLT NEXT ;IF BRNCH RECT LFT EDGE > PLYR X
MOVE *A0+,A1,W
SUB A9,A1
; JRNN NEXTNO
;;WENT NEG
; CLR A1
;NEXTNO
CMP A1,A10
JRLT NEXTA ;IF BRNCH RECT TOP EDGE > PLYR Y
MOVE *A0+,A1,W
CMP A1,A11
JRGT NEXTB ;IF BRNCH RECT RGT EDGE < PLYR X
MOVE *A0+,A1,W
ADDK 20,A1 ;GET ICON OFF TOP WALLS ;10
CMP A1,A10
JRGT NEXT0 ;IF BRNCH RECT BOT EDGE < PLYR Y
;TOUCHING WALL RECTANGLE
JRUC NOK
NEXT ADDI 48,A0
JRUC NEXT0
NEXTA ADDK 32,A0
JRUC NEXT0
NEXTB ADDK 16,A0
JRUC NEXT0
OUT
;NOT IN RECTANGLE
CLRC
RETS
LAYBMB
MOVI 60,B0
MOVI 5*60,B1
CALLA RANGRAND
CALLA PRCSLP
;A9=1-3
;LAY DOWN 1,2,3 BOMBS
;BLINK THEM OUT AFTER A TIME
;DIE
MOVE @HALT,A0
JRNE GAIN ;IF HALT ON, SKIP THIS
PUSH A9
MOVK 029,A9 ;DOUBLE BOMB WIDTH 20 WIDE
CALLR GET_VALID_XY
PULL A9
JRNC GOOD2
GAIN SLEEPK 4 ;ON HEAD OR IN RECTANGLE, TRY AGAIN
JRUC LAYBMB
GOOD2:
;A10,A11 ARE VALID
;LAY DOWN A9 BOMBS
CREATE CMAN,WAITBMB
DSJS A9,GOOD2
DIE
XYADJ .LONG 0,[0,0],[0,16],[12,8]
WAITBMB
MOVE A9,A0
SLL 5,A0
ADDI XYADJ,A0
MOVE *A0,A0,L
MOVY A0,A1
SRL 16,A1
ADD A1,A10
ANDI 0FFH,A0
ADD A0,A11
MOVI BMBIMG,A14
CALLR DO_ALL_STUFF
MOVE A0,A8
MOVE A10,*A8(OYPOS),W
MOVE A11,*A8(OXPOS),W
WAB
SLEEP 5*54-50 ;ABOUT 3 1/2 SECONDS ON SCREEN!
MOVE @HALT,A0
JRNZ WAB
;BLINK BMB
WAITBM
MOVK 7,A10
;ABOUT 1 SECOND OF BLINK
BKM
MOVE A8,A0
CALLA OBJOFF
SLEEPK 5
MOVE A8,A0
CALLA OBJON
SLEEPK 5
DSJS A10,BKM
SLEEPK 30
MOVE A8,A0
CALLA DELOBJ
DIE
CK_HDS:
;DON'T LAND ON PLAYERS HEAD!
;CHECK BOTH PLAYER 1 AND 2
; MOVB @BOSSON,A2
; JRNZ ICONOK
MOVE *A0(OYVAL),A2,L
MOVE *A0(OXVAL),A3,L
MOVE @WORLDTLY,A4,L
MOVE @WORLDTLX,A5,L
SUB A4,A2
SUB A5,A3
SRL 16,A2
SRL 16,A3
SUB A10,A2
ABS A2
SUBK 25,A2 ;30
JRLT NOICON
SUB A11,A3
ABS A3
SUBK 30,A3 ;40
JRGT ICONOK
NOICON: SETC
RETS
ICONOK:
CLRC ;OKAY
RETS
;
FIREX .EQU 1
SPDRX .EQU 2
SPRYX .EQU 3
HLPRX .EQU 4
XTRAX .EQU 5
GRENX .EQU 6
KEYX .EQU 7
RINGX .EQU 8
NSTPX .EQU 9
SHOEX .EQU 10
SMRTX .EQU 11
SHOE2X .EQU 12
BMBLTSX .EQU 13
ICINIT .LONG 0,FIREI,SPDRI,SPRYI,HLPRI,XTRAI
.LONG GRENI,KEYI,RINGI,NSTPI,SHOEI,SMARTI,SHOE2I,BMBLTI
***********************************************
ICN1
;FIRST LIST OF ICONS
;EACH ICON LISTED INDIVIDUALLY, TOTAL MUST = 30
.BYTE 0
;GUNS HERE
;FAST SPEED GUN
.BYTE SPDRX,SPDRX,SPDRX,SPDRX
;SPRAY
.BYTE SPRYX,SPRYX,SPRYX,SPRYX
;NOSTOP
.BYTE NSTPX,NSTPX,NSTPX
;GRENADE LAUNCHER
;FLAME THROWER
.BYTE FIREX,FIREX,FIREX
.BYTE FIREX,FIREX
;TENNIS SHOES
.BYTE SHOE2X,SHOE2X,SHOE2X
;SMART
.BYTE SMRTX,SMRTX,SMRTX,SMRTX
;HELPER BLADE
.BYTE HLPRX,HLPRX
;EXTRA MAN
.BYTE XTRAX
;RINGS
.BYTE RINGX,RINGX
;FLYING BOOTS
;KEY/MAP
.BYTE KEYX
;BOMBLETS
.BYTE BMBLTSX
.EVEN
***********************************************
***********************************************
ICN2
;USED IN WARP 1 LOCKDOWN
;EACH ICON LISTED INDIVIDUALLY, TOTAL MUST = 30
.BYTE 0
;GUNS HERE
;FAST SPEED GUN
.BYTE SPDRX,SPDRX,SPDRX
;SPRAY
.BYTE SPRYX,SPRYX,SPRYX
;NOSTOP
.BYTE NSTPX,NSTPX,NSTPX
;GRENADE LAUNCHER
;FLAME THROWER
.BYTE FIREX,FIREX,FIREX,FIREX,FIREX
***********************************************
;TENNIS SHOES
.BYTE SHOE2X,SHOE2X,SHOE2X,SHOE2X
;SMART
.BYTE SMRTX,SMRTX,SMRTX
;HELPER BLADE
.BYTE HLPRX
;EXTRA MAN
.BYTE XTRAX
;RINGS
.BYTE RINGX,RINGX
;FLYING BOOTS
;KEY/MAP
.BYTE KEYX
.BYTE KEYX
.BYTE KEYX
;BOMBLETS
.BYTE BMBLTSX,BMBLTSX
.EVEN
***********************************************
***********************************************
ICN3
;LIST FOR SECRET PATH
;EACH ICON LISTED INDIVIDUALLY, TOTAL MUST = 30
.BYTE 0
;GUNS HERE
;FAST SPEED GUN
.BYTE SPDRX
;SPRAY
.BYTE SPRYX,SPRYX,SPRYX,SPRYX
;NOSTOP
.BYTE NSTPX,NSTPX,NSTPX
;GRENADE LAUNCHER
;FLAME THROWER
.BYTE FIREX,FIREX,FIREX,FIREX,FIREX
***********************************************
;TENNIS SHOES
.BYTE SHOE2X,SHOE2X,SHOE2X,SHOE2X
;SMART
.BYTE SMRTX,SMRTX
;HELPER BLADE
.BYTE HLPRX,HLPRX
;EXTRA MAN
.BYTE XTRAX
;RINGS
.BYTE RINGX,RINGX
;FLYING BOOTS
.BYTE SHOEX,SHOEX
;KEY/MAP
.BYTE KEYX,KEYX
;BOMBLETS
.BYTE BMBLTSX,BMBLTSX
.EVEN
***********************************************
***********************************************
ICN4
;USED ON ROAD
;EACH ICON LISTED INDIVIDUALLY, TOTAL MUST = 30
.BYTE 0,0,0,0,0,0,0,0,0,0,0,0,0
;GUNS HERE
;FAST SPEED GUN
;SPRAY
;NOSTOP
;GRENADE LAUNCHER
;FLAME THROWER
;TENNIS SHOES
;SMART
.BYTE SMRTX,SMRTX
.BYTE SMRTX,SMRTX,SMRTX
;HELPER BLADE
.BYTE HLPRX,HLPRX
.BYTE HLPRX,HLPRX,HLPRX
;EXTRA MAN
.BYTE XTRAX
.BYTE XTRAX
;RINGS
.BYTE RINGX,RINGX,RINGX
;FLYING BOOTS
;KEY/MAP
;BOMBLETS
.BYTE BMBLTSX
.BYTE BMBLTSX
.EVEN
***********************************************
ICN5
;ORCUS BOSS LIST OF ICONS
;EACH ICON LISTED INDIVIDUALLY, TOTAL MUST = 30
.BYTE 0
;GUNS HERE
;FAST SPEED GUN
.BYTE SPDRX,SPDRX
;SPRAY
.BYTE SPRYX,SPRYX,SPRYX,SPRYX,SPRYX
.BYTE SPRYX
.BYTE SPRYX
.BYTE SPRYX
;NOSTOP
.BYTE NSTPX,NSTPX,NSTPX,NSTPX
;GRENADE LAUNCHER
.BYTE GRENX,GRENX
.BYTE GRENX,GRENX
.BYTE GRENX
;FLAME THROWER
.BYTE FIREX
.BYTE FIREX
.BYTE FIREX
;TENNIS SHOES
;SMART
;HELPER BLADE
.BYTE HLPRX
.BYTE HLPRX
;EXTRA MAN
.BYTE XTRAX
.BYTE XTRAX
.BYTE XTRAX
;RINGS
.BYTE RINGX,RINGX,RINGX
;FLYING BOOTS
;KEY/MAP
;BOMBLETS
.EVEN
***********************************************
ICN5A
;LAST BOSS LIST OF ICONS
;EACH ICON LISTED INDIVIDUALLY, TOTAL MUST = 30
.BYTE 0
;GUNS HERE
;FAST SPEED GUN
.BYTE SPDRX,SPDRX,SPDRX,SPDRX
;SPRAY
.BYTE SPRYX,SPRYX,SPRYX,SPRYX,SPRYX
;NOSTOP
.BYTE NSTPX,NSTPX,NSTPX,NSTPX
;GRENADE LAUNCHER
.BYTE GRENX,GRENX
.BYTE GRENX,GRENX
.BYTE GRENX
;FLAME THROWER
.BYTE FIREX
.BYTE FIREX
.BYTE FIREX
;TENNIS SHOES
;SMART
.BYTE SMRTX,SMRTX
;HELPER BLADE
.BYTE HLPRX
;EXTRA MAN
;RINGS
.BYTE RINGX
;FLYING BOOTS
.BYTE SHOEX,SHOEX
; .BYTE SHOEX
;KEY/MAP
.BYTE KEYX
.BYTE KEYX
.BYTE KEYX
;BOMBLETS
.EVEN
***********************************************
***********************************************
ICN6
;USED ON ROAD WITH LOTS OF JEEPS
;EACH ICON LISTED INDIVIDUALLY, TOTAL MUST = 30
.BYTE 0,0,0,0,0,0,0,0,0
;GUNS HERE
;FAST SPEED GUN
;SPRAY
;NOSTOP
;GRENADE LAUNCHER
;FLAME THROWER
***********************************************
;TENNIS SHOES
.BYTE SHOE2X,SHOE2X,SHOE2X
.BYTE SHOE2X,SHOE2X,SHOE2X
.BYTE SHOE2X,SHOE2X
;SMART
;HELPER BLADE
;EXTRA MAN
.BYTE XTRAX
.BYTE XTRAX
.BYTE XTRAX
;RINGS
.BYTE RINGX
.BYTE RINGX
;FLYING BOOTS
; .BYTE SHOEX
;KEY/MAP
.BYTE KEYX
.BYTE KEYX
.BYTE KEYX
.BYTE KEYX
.BYTE KEYX
.BYTE KEYX
.BYTE KEYX
;BOMBLETS
.BYTE BMBLTSX
.EVEN
***********************************************
***********************************************
ICN7
;USED ON TARMAC
;EACH ICON LISTED INDIVIDUALLY, TOTAL MUST = 30
.BYTE 0,0,0,0,0,0,0,0,0,0,0,0
.BYTE 0,0
;GUNS HERE
;FAST SPEED GUN
;SPRAY
;NOSTOP
;GRENADE LAUNCHER
;FLAME THROWER
***********************************************
;TENNIS SHOES
.BYTE SHOE2X,SHOE2X,SHOE2X
.BYTE SHOE2X,SHOE2X
.BYTE SHOE2X,SHOE2X,SHOE2X
.BYTE SHOE2X,SHOE2X
;SMART
;HELPER BLADE
;EXTRA MAN
.BYTE XTRAX
.BYTE XTRAX
;RINGS
.BYTE RINGX
;FLYING BOOTS
.BYTE SHOEX
.BYTE SHOEX
.BYTE SHOEX
;KEY/MAP
; .BYTE KEYX
; .BYTE KEYX
; .BYTE KEYX
; .BYTE KEYX
; .BYTE KEYX
;BOMBLETS
.EVEN
***********************************************
ICN8
;EACH ICON LISTED INDIVIDUALLY, TOTAL MUST = 30
.BYTE 0
;GUNS HERE
;FAST SPEED GUN
;SPRAY
.BYTE SPRYX
.BYTE SPRYX
.BYTE SPRYX
.BYTE SPRYX
;NOSTOP
.BYTE NSTPX,NSTPX
.BYTE NSTPX
.BYTE NSTPX
;GRENADE LAUNCHER
;FLAME THROWER
.BYTE FIREX,FIREX
.BYTE FIREX,FIREX
.BYTE FIREX,FIREX
.BYTE FIREX,FIREX
;TENNIS SHOES
.BYTE SHOE2X,SHOE2X
.BYTE SHOE2X,SHOE2X
.BYTE SHOE2X,SHOE2X
;SMART
.BYTE SMRTX,SMRTX
;HELPER BLADE
.BYTE HLPRX
.BYTE HLPRX
;EXTRA MAN
.BYTE XTRAX
;RINGS
;FLYING BOOTS
;KEY/MAP
.BYTE KEYX
.BYTE KEYX
.BYTE KEYX
;BOMBLETS
.EVEN
***********************************************
ICN9
;FIRST LIST OF ICONS
;EACH ICON LISTED INDIVIDUALLY, TOTAL MUST = 30
.BYTE 0
;GUNS HERE
;FAST SPEED GUN
.BYTE SPDRX,SPDRX
;SPRAY
.BYTE SPRYX,SPRYX,SPRYX
;NOSTOP
.BYTE NSTPX,NSTPX,NSTPX,NSTPX
;GRENADE LAUNCHER
;FLAME THROWER
.BYTE FIREX,FIREX,FIREX
.BYTE FIREX,FIREX,FIREX,FIREX
;TENNIS SHOES
.BYTE SHOE2X,SHOE2X,SHOE2X,SHOE2X
;SMART
.BYTE SMRTX,SMRTX,SMRTX
;HELPER BLADE
.BYTE HLPRX,HLPRX
;EXTRA MAN
.BYTE XTRAX
.BYTE XTRAX
.BYTE XTRAX
;RINGS
.BYTE RINGX,RINGX
.BYTE RINGX,RINGX
;FLYING BOOTS
;KEY/MAP
;BOMBLETS
.EVEN
***********************************************
HLPRI:
.LONG 0,0,BLADE
.WORD 71,DMAWNZ,CLSNEUT|TYPICON|SUBHLP
.LONG 0,0
KEYI:
.LONG 0,0,KEY
.WORD 71,DMAWNZ,CLSNEUT|TYPICON|SUBKEY
.LONG 0,0
NSTPI:
.LONG 0,0,NONSTOP
.WORD 71,DMAWNZ,CLSNEUT|TYPICON|SUBNSTP
.LONG 0,0
RINGI:
.LONG 0,0,RING
.WORD 71,DMAWNZ,CLSNEUT|TYPICON|SUBRING
.LONG 0,0
GRENI:
.LONG 0,0,GRENADE
.WORD 71,DMAWNZ,CLSNEUT|TYPICON|SUBGREN
.LONG 0,0
XTRAI:
.LONG 0,0,PLAYER
.WORD 71,DMAWNZ,CLSNEUT|TYPICON|SUBMAN
.LONG 0,0
SPRYI:
.LONG 0,0,SPRAY
.WORD 71,DMAWNZ,CLSNEUT|TYPICON|SUBSPRY1
.LONG 0,0
SPDRI:
.LONG 0,0,SPDGUN
.WORD 71,DMAWNZ|M_FLIPH,CLSNEUT|TYPICON|SUBSPDG
.LONG 0,0
FIREI:
.LONG 0,0,FIRE
.WORD 71,DMAWNZ,CLSNEUT|TYPICON|SUBFIRE
.LONG 0,0
SHOEI:
.LONG 0,0,SHOES
.WORD 71,DMAWNZ,CLSNEUT|TYPICON|SUBSHOE
.LONG 0,0
SHOE2I:
.LONG 0,0,SHOES2
.WORD 71,DMAWNZ,CLSNEUT|TYPICON|SUBSHOE
.LONG 0,0
BMBLTI:
.LONG 0,0,BMBLETS
.WORD 71,DMAWNZ|M_FLIPH,CLSNEUT|TYPICON|SUBBLET
.LONG 0,0
SMARTI: