monoprop/flake.nix at main · Algorithmiq/monoprop · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
{
  description = "monoprop: because your operators deserve to propagate at escape velocity.";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs =
    {
      nixpkgs,
      flake-utils,
      ...
    }:
    let
      monopropOverlay = final: _prev: {
        monoprop =
          let
            python = final.python312;
            scikit-build-core = python.pkgs.scikit-build-core.overridePythonAttrs (_: rec {
              version = "1.0.3";
              src = final.fetchPypi {
                pname = "scikit_build_core";
                inherit version;
                hash = "sha256-pNegWXjuN5dcN3Q1EMiZHi3rzn74OvsKB8DFdv1PFug=";
              };
              doCheck = false;
            });
            nanobind = python.pkgs.callPackage ./nix/nanobind.nix { };
            nanobind-backend = python.pkgs.callPackage ./nix/nanobind-backend.nix {
              inherit nanobind;
            };
          in
          python.pkgs.callPackage ./nix/monoprop.nix {
            inherit scikit-build-core nanobind nanobind-backend;
          };

        monoprop-mpi = final.monoprop.override { withMPI = true; };
      };
    in
    {
      overlays.default = monopropOverlay;
    }
    // flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs {
          inherit system;
          overlays = [ monopropOverlay ];
        };
        python = pkgs.python312;
        inherit (pkgs) monoprop monoprop-mpi;

        replEnv = python.withPackages (ps: [
          monoprop
          ps.numpy
        ]);
      in
      {
        packages = {
          default = monoprop;
          inherit monoprop monoprop-mpi;
        };

        apps.default = {
          type = "app";
          program = "${replEnv}/bin/python";
          meta.description = "Python interpreter with monoprop importable";
        };

        devShells.default = pkgs.callPackage ./nix/devshell.nix { inherit python; };

        checks = {
          inherit monoprop;
        };

        formatter = pkgs.nixfmt-tree;
      }
    );
}